home *** CD-ROM | disk | FTP | other *** search
/ Programming Languages Suite / ProgramD2.iso / Borland / Borland Pascal with Objects 7.0 / BGIDEMO.ZIP / BGIDEMO.PAS < prev    next >
Pascal/Delphi Source File  |  1992-10-27  |  45KB  |  1,616 lines
  1. {************************************************}
  2. {                                                }
  3. {   BGI Demo Program                             }
  4. {   Copyright (c) 1992 by Borland International  }
  5. {                                                }
  6. {************************************************}
  7.  
  8. program BGIDemo;
  9.  
  10. (*
  11.   Borland Graphics Interface (BGI) demonstration
  12.   program. This program shows how to use many features of
  13.   the Graph unit.
  14.  
  15.   NOTE: to have this demo use the IBM8514 driver, specify a
  16.   conditional define constant "Use8514" (using the {$DEFINE}
  17.   directive or Options\Compiler\Conditional defines) and then
  18.   re-compile.
  19. *)
  20.  
  21. uses
  22. {$IFDEF DPMI}
  23.   Crt, Dos, Graph, WinAPI;
  24. {$ELSE}
  25.   Crt, Dos, Graph;
  26. {$ENDIF}
  27.  
  28. const
  29.   { The ten fonts available }
  30.   Fonts : array[0..10] of string[17] =
  31.   ('DefaultFont', 'TriplexFont', 'SmallFont', 'SansSerifFont', 'GothicFont',
  32.    'ScriptFont', 'SimplexFont', 'TriplexScriptFont', 'ComplexFont', 
  33.    'EuropeanFont', 'BoldFont');
  34.  
  35.   { The five predefined line styles supported }
  36.   LineStyles : array[0..4] of string[9] =
  37.   ('SolidLn', 'DottedLn', 'CenterLn', 'DashedLn', 'UserBitLn');
  38.  
  39.   { The twelve predefined fill styles supported }
  40.   FillStyles : array[0..11] of string[14] =
  41.   ('EmptyFill', 'SolidFill', 'LineFill', 'LtSlashFill', 'SlashFill',
  42.    'BkSlashFill', 'LtBkSlashFill', 'HatchFill', 'XHatchFill',
  43.    'InterleaveFill', 'WideDotFill', 'CloseDotFill');
  44.  
  45.   { The two text directions available }
  46.   TextDirect : array[0..1] of string[8] = ('HorizDir', 'VertDir');
  47.  
  48.   { The Horizontal text justifications available }
  49.   HorizJust  : array[0..2] of string[10] = ('LeftText', 'CenterText', 'RightText');
  50.  
  51.   { The vertical text justifications available }
  52.   VertJust   : array[0..2] of string[10] = ('BottomText', 'CenterText', 'TopText');
  53.  
  54. var
  55.   GraphDriver : integer;  { The Graphics device driver }
  56.   GraphMode   : integer;  { The Graphics mode value }
  57.   MaxX, MaxY  : word;     { The maximum resolution of the screen }
  58.   ErrorCode   : integer;  { Reports any graphics errors }
  59.   MaxColor    : word;     { The maximum color value available }
  60.   OldExitProc : Pointer;  { Saves exit procedure address }
  61.   VESA16      : Integer;  { Driver number of 16 color driver }
  62.  
  63. type
  64.   VgaInfoBlock = record
  65.     VESASignature: array[0..3] of Byte;
  66.     VESAVersion: Word;
  67.     OEMStringPtr: Pointer;
  68.     Capabilities: array[0..3] of Byte;
  69.     VideoModePtr: Pointer;
  70.   end;
  71.  
  72. const
  73.   VESA16Modes: array[0..2] of Word =
  74.     ($0102, $0104, $0106);
  75.  
  76. { Scan the supported mode table for the highest mode this card
  77.   will provide
  78. }
  79.  
  80. function GetHighestCap(Table: Pointer; Modes: Word; Size: Integer): Integer;
  81.   near; assembler;
  82. asm
  83.         XOR     AX,AX
  84.         LES     DI, Table
  85. @@1:
  86.         MOV     SI, Modes
  87.         ADD     SI, Size
  88.         ADD     SI, Size
  89.         MOV     BX, ES:[DI]
  90.         CMP     BX, 0FFFFH
  91.         JE      @@4
  92.         INC     DI
  93.         INC     DI
  94.         MOV     CX,Size
  95. @@2:
  96.         CMP     BX,[SI]
  97.         JZ      @@3
  98.         DEC     SI
  99.         DEC     SI
  100.         LOOP    @@2
  101. @@3:
  102.         CMP     AX,CX
  103.         JA      @@1
  104.         MOV     AX,CX
  105.         JMP     @@1
  106. @@4:
  107. end;
  108.  
  109. {$IFDEF DPMI}
  110. type
  111.   TRealRegs = record
  112.     RealEDI: Longint;
  113.     RealESI: Longint;
  114.     RealEBP: Longint;
  115.     Reserved: Longint;
  116.     RealEBX: Longint;
  117.     RealEDX: Longint;
  118.     RealECX: Longint;
  119.     RealEAX: Longint;
  120.     RealFlags: Word;
  121.     RealES: Word;
  122.     RealDS: Word;
  123.     RealFS: Word;
  124.     RealGS: Word;
  125.     RealIP: Word;
  126.     RealCS: Word;
  127.     RealSP: Word;
  128.     RealSS: Word;
  129.   end;
  130.  
  131. function DetectVesa16: Integer; far; assembler;
  132. var
  133.   Segment, Selector, VesaCap: Word;
  134. asm
  135. {$IFOPT G+}
  136.         PUSH    0000H
  137.         PUSH    0100H
  138. {$ELSE}
  139.         XOR     AX,AX
  140.         PUSH    AX
  141.         INC     AH
  142.         PUSH    AX
  143. {$ENDIF}
  144.         CALL    GlobalDosAlloc
  145.         MOV     Segment,DX
  146.         MOV     Selector,AX
  147.         MOV     DI,OFFSET RealModeRegs
  148.         MOV     WORD PTR [DI].TRealRegs.RealSP, 0
  149.         MOV     WORD PTR [DI].TRealRegs.RealSS, 0
  150.         MOV     WORD PTR [DI].TRealRegs.RealEAX, 4F00H
  151.         MOV     WORD PTR [DI].TRealRegs.RealES, DX
  152.         MOV     WORD PTR [DI].TRealRegs.RealEDI, 0
  153.         MOV     AX,DS
  154.         MOV     ES,AX
  155.         MOV     AX,0300H
  156.         MOV     BX,0010H
  157.         XOR     CX,CX
  158.         INT     31H
  159.         MOV     DI,OFFSET RealModeRegs
  160.         MOV     AX,grError
  161.         PUSH    AX
  162.         CMP     WORD PTR [DI].TRealRegs.RealEAX,004FH
  163.         JNZ     @@Exit
  164.         POP     AX
  165.         MOV     ES,Selector
  166.         XOR     DI,DI
  167.         CMP     ES:[DI].VgaInfoBlock.VESASignature.Word[0], 'EV'
  168.         JNZ     @@Exit
  169.         CMP     ES:[DI].VgaInfoBlock.VESASignature.Word[2], 'AS'
  170.         JNZ     @@Exit
  171.         MOV     AX,0000
  172.         MOV     CX,1
  173.         INT     31H
  174.         MOV     VesaCap,AX
  175.         MOV     DX,ES:[DI].VgaInfoBlock.VideoModePtr.Word[2]
  176.         MOV     CX,4
  177.         XOR     AX,AX
  178. @@Convert:
  179.         SHL     DX,1
  180.         RCL     AX,1
  181.         LOOP    @@Convert
  182.         ADD     DX,ES:[DI].VgaInfoBlock.VideoModePtr.Word[0]
  183.         ADC     AX,0
  184.         MOV     CX,AX
  185.         MOV     BX,VesaCap
  186.         MOV     AX,0007H
  187.         INT     31H
  188.         INC     AX
  189.         XOR     CX,CX
  190.         MOV     DX,0FFFFH
  191.         INT     31H
  192.         MOV     ES,BX
  193.         PUSH    ES
  194.         PUSH    DI
  195. {$IFOPT G+}
  196.         PUSH    OFFSET Vesa16Modes
  197.         PUSH    0003H
  198. {$ELSE}
  199.         MOV     SI, OFFSET Vesa16Modes
  200.         PUSH    SI
  201.         MOV     AX, 5
  202.         PUSH    AX
  203. {$ENDIF}
  204.         CALL    GetHighestCap
  205.         PUSH    AX
  206.         MOV     BX,VesaCap
  207.         MOV     AX,0001H
  208.         INT     31H
  209. @@Exit:
  210.         PUSH    Selector
  211.         CALL    GlobalDosFree
  212.         POP     AX
  213. end;
  214. {$ELSE}
  215. function DetectVesa16: Integer; far; assembler;
  216. var
  217.   VesaInfo: array[0..255] of Byte;
  218. asm
  219.         MOV     AX,SS
  220.         MOV     ES,AX
  221.         LEA     DI,VesaInfo
  222.         MOV     AX,4F00H
  223.         INT     10H
  224.         CMP     AX,004FH
  225.         MOV     AX,grError
  226.         JNZ     @@Exit
  227.         CMP     ES:[DI].VgaInfoBlock.VESASignature.Word[0], 'EV'
  228.         JNZ     @@Exit
  229.         CMP     ES:[DI].VgaInfoBlock.VESASignature.Word[2], 'AS'
  230.         JNZ     @@Exit
  231.         LES     DI,ES:[DI].VgaInfoBlock.VideoModePtr
  232.         PUSH    ES
  233.         PUSH    DI
  234.         MOV     AX, OFFSET Vesa16Modes
  235.         PUSH    AX
  236.         MOV     AX,3
  237.         PUSH    AX
  238.         CALL    GetHighestCap
  239. @@Exit:
  240. end;
  241. {$ENDIF}
  242.  
  243. {$F+}
  244. procedure MyExitProc;
  245. begin
  246.   ExitProc := OldExitProc; { Restore exit procedure address }
  247.   CloseGraph;              { Shut down the graphics system }
  248. end; { MyExitProc }
  249. {$F-}
  250.  
  251. procedure Initialize;
  252. { Initialize graphics and report any errors that may occur }
  253. var
  254.   InGraphicsMode : boolean; { Flags initialization of graphics mode }
  255.   PathToDriver   : string;  { Stores the DOS path to *.BGI & *.CHR }
  256. begin
  257.   { when using Crt and graphics, turn off Crt's memory-mapped writes }
  258.   DirectVideo := False;
  259.   OldExitProc := ExitProc;                { save previous exit proc }
  260.   ExitProc := @MyExitProc;                { insert our exit proc in chain }
  261.   PathToDriver := '';
  262.   repeat
  263.  
  264.  
  265.     VESA16 := InstallUserDriver('VESA16', @DetectVESA16);
  266.  
  267. {$IFDEF Use8514}                          { check for Use8514 $DEFINE }
  268.     GraphDriver := IBM8514;
  269.     GraphMode := IBM8514Hi;
  270. {$ELSE}
  271.     GraphDriver := Detect;                { use autodetection }
  272. {$ENDIF}
  273.  
  274.     InitGraph(GraphDriver, GraphMode, PathToDriver);
  275.     ErrorCode := GraphResult;             { preserve error return }
  276.     if ErrorCode <> grOK then             { error? }
  277.     begin
  278.       Writeln('Graphics error: ', GraphErrorMsg(ErrorCode));
  279.       if ErrorCode = grFileNotFound then  { Can't find driver file }
  280.       begin
  281.         Writeln('Enter full path to BGI driver or type <Ctrl-Break> to quit:');
  282.         Readln(PathToDriver);
  283.         Writeln;
  284.       end
  285.       else
  286.         Halt(1);                          { Some other error: terminate }
  287.     end;
  288.   until ErrorCode = grOK;
  289.   Randomize;                { init random number generator }
  290.   MaxColor := GetMaxColor;  { Get the maximum allowable drawing color }
  291.   MaxX := GetMaxX;          { Get screen resolution values }
  292.   MaxY := GetMaxY;
  293. end; { Initialize }
  294.  
  295. function Int2Str(L : LongInt) : string;
  296. { Converts an integer to a string for use with OutText, OutTextXY }
  297. var
  298.   S : string;
  299. begin
  300.   Str(L, S);
  301.   Int2Str := S;
  302. end; { Int2Str }
  303.  
  304. function RandColor : word;
  305. { Returns a Random non-zero color value that is within the legal
  306.   color range for the selected device driver and graphics mode.
  307.   MaxColor is set to GetMaxColor by Initialize }
  308. begin
  309.   RandColor := Random(MaxColor)+1;
  310. end; { RandColor }
  311.  
  312. procedure DefaultColors;
  313. { Select the maximum color in the Palette for the drawing color }
  314. begin
  315.   SetColor(MaxColor);
  316. end; { DefaultColors }
  317.  
  318. procedure DrawBorder;
  319. { Draw a border around the current view port }
  320. var
  321.   ViewPort : ViewPortType;
  322. begin
  323.   DefaultColors;
  324.   SetLineStyle(SolidLn, 0, NormWidth);
  325.   GetViewSettings(ViewPort);
  326.   with ViewPort do
  327.     Rectangle(0, 0, x2-x1, y2-y1);
  328. end; { DrawBorder }
  329.  
  330. procedure FullPort;
  331. { Set the view port to the entire screen }
  332. begin
  333.   SetViewPort(0, 0, MaxX, MaxY, ClipOn);
  334. end; { FullPort }
  335.  
  336. procedure MainWindow(Header : string);
  337. { Make a default window and view port for demos }
  338. begin
  339.   DefaultColors;                           { Reset the colors }
  340.   ClearDevice;                             { Clear the screen }
  341.   SetTextStyle(DefaultFont, HorizDir, 1);  { Default text font }
  342.   SetTextJustify(CenterText, TopText);     { Left justify text }
  343.   FullPort;                                { Full screen view port }
  344.   OutTextXY(MaxX div 2, 2, Header);        { Draw the header }
  345.   { Draw main window }
  346.   SetViewPort(0, TextHeight('M')+4, MaxX, MaxY-(TextHeight('M')+4), ClipOn);
  347.   DrawBorder;                              { Put a border around it }
  348.   { Move the edges in 1 pixel on all sides so border isn't in the view port }
  349.   SetViewPort(1, TextHeight('M')+5, MaxX-1, MaxY-(TextHeight('M')+5), ClipOn);
  350. end; { MainWindow }
  351.  
  352. procedure StatusLine(Msg : string);
  353. { Display a status line at the bottom of the screen }
  354. begin
  355.   FullPort;
  356.   DefaultColors;
  357.   SetTextStyle(DefaultFont, HorizDir, 1);
  358.   SetTextJustify(CenterText, TopText);
  359.   SetLineStyle(SolidLn, 0, NormWidth);
  360.   SetFillStyle(EmptyFill, 0);
  361.   Bar(0, MaxY-(TextHeight('M')+4), MaxX, MaxY);      { Erase old status line }
  362.   Rectangle(0, MaxY-(TextHeight('M')+4), MaxX, MaxY);
  363.   OutTextXY(MaxX div 2, MaxY-(TextHeight('M')+2), Msg);
  364.   { Go back to the main window }
  365.   SetViewPort(1, TextHeight('M')+5, MaxX-1, MaxY-(TextHeight('M')+5), ClipOn);
  366. end; { StatusLine }
  367.  
  368. procedure WaitToGo;
  369. { Wait for the user to abort the program or continue }
  370. const
  371.   Esc = #27;
  372. var
  373.   Ch : char;
  374. begin
  375.   StatusLine('Esc aborts or press a key...');
  376.   repeat until KeyPressed;
  377.   Ch := ReadKey;
  378.   if ch = #0 then ch := readkey;      { trap function keys }
  379.   if Ch = Esc then
  380.     Halt(0)                           { terminate program }
  381.   else
  382.     ClearDevice;                      { clear screen, go on with demo }
  383. end; { WaitToGo }
  384.  
  385. procedure GetDriverAndMode(var DriveStr, ModeStr : string);
  386. { Return strings describing the current device driver and graphics mode
  387.   for display of status report }
  388. begin
  389.   DriveStr := GetDriverName;
  390.   ModeStr := GetModeName(GetGraphMode);
  391. end; { GetDriverAndMode }
  392.  
  393. procedure ReportStatus;
  394. { Display the status of all query functions after InitGraph }
  395. const
  396.   X = 10;
  397. var
  398.   ViewInfo   : ViewPortType;     { Parameters for inquiry procedures }
  399.   LineInfo   : LineSettingsType;
  400.   FillInfo   : FillSettingsType;
  401.   TextInfo   : TextSettingsType;
  402.   Palette    : PaletteType;
  403.   DriverStr  : string;           { Driver and mode strings }
  404.   ModeStr    : string;
  405.   Y          : word;
  406.  
  407. procedure WriteOut(S : string);
  408. { Write out a string and increment to next line }
  409. begin
  410.   OutTextXY(X, Y, S);
  411.   Inc(Y, TextHeight('M')+2);
  412. end; { WriteOut }
  413.  
  414. begin { ReportStatus }
  415.   GetDriverAndMode(DriverStr, ModeStr);   { Get current settings }
  416.   GetViewSettings(ViewInfo);
  417.   GetLineSettings(LineInfo);
  418.   GetFillSettings(FillInfo);
  419.   GetTextSettings(TextInfo);
  420.   GetPalette(Palette);
  421.  
  422.   Y := 4;
  423.   MainWindow('Status report after InitGraph');
  424.   SetTextJustify(LeftText, TopText);
  425.   WriteOut('Graphics device    : '+DriverStr);
  426.   WriteOut('Graphics mode      : '+ModeStr);
  427.   WriteOut('Screen resolution  : (0, 0, '+Int2Str(GetMaxX)+', '+Int2Str(GetMaxY)+')');
  428.   with ViewInfo do
  429.   begin
  430.     WriteOut('Current view port  : ('+Int2Str(x1)+', '+Int2Str(y1)+', '+Int2Str(x2)+', '+Int2Str(y2)+')');
  431.     if ClipOn then
  432.       WriteOut('Clipping           : ON')
  433.     else
  434.       WriteOut('Clipping           : OFF');
  435.   end;
  436.   WriteOut('Current position   : ('+Int2Str(GetX)+', '+Int2Str(GetY)+')');
  437.   WriteOut('Palette entries    : '+Int2Str(Palette.Size));
  438.   WriteOut('GetMaxColor        : '+Int2Str(GetMaxColor));
  439.   WriteOut('Current color      : '+Int2Str(GetColor));
  440.   with LineInfo do
  441.   begin
  442.     WriteOut('Line style         : '+LineStyles[LineStyle]);
  443.     WriteOut('Line thickness     : '+Int2Str(Thickness));
  444.   end;
  445.   with FillInfo do
  446.   begin
  447.     WriteOut('Current fill style : '+FillStyles[Pattern]);
  448.     WriteOut('Current fill color : '+Int2Str(Color));
  449.   end;
  450.   with TextInfo do
  451.   begin
  452.     WriteOut('Current font       : '+Fonts[Font]);
  453.     WriteOut('Text direction     : '+TextDirect[Direction]);
  454.     WriteOut('Character size     : '+Int2Str(CharSize));
  455.     WriteOut('Horizontal justify : '+HorizJust[Horiz]);
  456.     WriteOut('Vertical justify   : '+VertJust[Vert]);
  457.   end;
  458.   WaitToGo;
  459. end; { ReportStatus }
  460.  
  461. procedure FillEllipsePlay;
  462. { Random filled ellipse demonstration }
  463. const
  464.   MaxFillStyles = 12; { patterns 0..11 }
  465. var
  466.   MaxRadius : word;
  467.   FillColor : integer;
  468. begin
  469.   MainWindow('FillEllipse demonstration');
  470.   StatusLine('Esc aborts or press a key');
  471.   MaxRadius := MaxY div 10;
  472.   SetLineStyle(SolidLn, 0, NormWidth);
  473.   repeat
  474.     FillColor := RandColor;
  475.     SetColor(FillColor);
  476.     SetFillStyle(Random(MaxFillStyles), FillColor);
  477.     FillEllipse(Random(MaxX), Random(MaxY),
  478.                 Random(MaxRadius), Random(MaxRadius));
  479.   until KeyPressed;
  480.   WaitToGo;
  481. end; { FillEllipsePlay }
  482.  
  483. procedure SectorPlay;
  484. { Draw random sectors on the screen }
  485. const
  486.   MaxFillStyles = 12; { patterns 0..11 }
  487. var
  488.   MaxRadius : word;
  489.   FillColor : integer;
  490.   EndAngle  : integer;
  491. begin
  492.   MainWindow('Sector demonstration');
  493.   StatusLine('Esc aborts or press a key');
  494.   MaxRadius := MaxY div 10;
  495.   SetLineStyle(SolidLn, 0, NormWidth);
  496.   repeat
  497.     FillColor := RandColor;
  498.     SetColor(FillColor);
  499.     SetFillStyle(Random(MaxFillStyles), FillColor);
  500.     EndAngle := Random(360);
  501.     Sector(Random(MaxX), Random(MaxY), Random(EndAngle), EndAngle,
  502.            Random(MaxRadius), Random(MaxRadius));
  503.   until KeyPressed;
  504.   WaitToGo;
  505. end; { SectorPlay }
  506.  
  507. procedure WriteModePlay;
  508. { Demonstrate the SetWriteMode procedure for XOR lines }
  509. const
  510.   DelayValue = 50;  { milliseconds to delay }
  511. var
  512.   ViewInfo      : ViewPortType;
  513.   Color         : word;
  514.   Left, Top     : integer;
  515.   Right, Bottom : integer;
  516.   Step          : integer; { step for rectangle shrinking }
  517. begin
  518.   MainWindow('SetWriteMode demonstration');
  519.   StatusLine('Esc aborts or press a key');
  520.   GetViewSettings(ViewInfo);
  521.   Left := 0;
  522.   Top := 0;
  523.   with ViewInfo do
  524.   begin
  525.     Right := x2-x1;
  526.     Bottom := y2-y1;
  527.   end;
  528.   Step := Bottom div 50;
  529.   SetColor(GetMaxColor);
  530.   Line(Left, Top, Right, Bottom);
  531.   Line(Left, Bottom, Right, Top);
  532.   SetWriteMode(XORPut);                    { Set XOR write mode }
  533.   repeat
  534.     Line(Left, Top, Right, Bottom);        { Draw XOR lines }
  535.     Line(Left, Bottom, Right, Top);
  536.     Rectangle(Left, Top, Right, Bottom);   { Draw XOR rectangle }
  537.     Delay(DelayValue);                     { Wait }
  538.     Line(Left, Top, Right, Bottom);        { Erase lines }
  539.     Line(Left, Bottom, Right, Top);
  540.     Rectangle(Left, Top, Right, Bottom);   { Erase rectangle }
  541.     if (Left+Step < Right) and (Top+Step < Bottom) then
  542.       begin
  543.         Inc(Left, Step);                  { Shrink rectangle }
  544.         Inc(Top, Step);
  545.         Dec(Right, Step);
  546.         Dec(Bottom, Step);
  547.       end
  548.     else
  549.       begin
  550.         Color := RandColor;                { New color }
  551.         SetColor(Color);
  552.         Left := 0;                         { Original large rectangle }
  553.         Top := 0;
  554.         with ViewInfo do
  555.         begin
  556.           Right := x2-x1;
  557.           Bottom := y2-y1;
  558.         end;
  559.       end;
  560.   until KeyPressed;
  561.   SetWriteMode(CopyPut);                   { back to overwrite mode }
  562.   WaitToGo;
  563. end; { WriteModePlay }
  564.  
  565. procedure AspectRatioPlay;
  566. { Demonstrate  SetAspectRatio command }
  567. var
  568.   ViewInfo   : ViewPortType;
  569.   CenterX    : integer;
  570.   CenterY    : integer;
  571.   Radius     : word;
  572.   Xasp, Yasp : word;
  573.   i          : integer;
  574.   RadiusStep : word;
  575. begin
  576.   MainWindow('SetAspectRatio demonstration');
  577.   GetViewSettings(ViewInfo);
  578.   with ViewInfo do
  579.   begin
  580.     CenterX := (x2-x1) div 2;
  581.     CenterY := (y2-y1) div 2;
  582.     Radius := 3*((y2-y1) div 5);
  583.   end;
  584.   RadiusStep := (Radius div 30);
  585.   Circle(CenterX, CenterY, Radius);
  586.   GetAspectRatio(Xasp, Yasp);
  587.   for i := 1 to 30 do
  588.   begin
  589.     SetAspectRatio(Xasp, Yasp+(I*GetMaxX));    { Increase Y aspect factor }
  590.     Circle(CenterX, CenterY, Radius);
  591.     Dec(Radius, RadiusStep);                   { Shrink radius }
  592.   end;
  593.   Inc(Radius, RadiusStep*30);
  594.   for i := 1 to 30 do
  595.   begin
  596.     SetAspectRatio(Xasp+(I*GetMaxX), Yasp);    { Increase X aspect factor }
  597.     if Radius > RadiusStep then
  598.       Dec(Radius, RadiusStep);                 { Shrink radius }
  599.     Circle(CenterX, CenterY, Radius);
  600.   end;
  601.   SetAspectRatio(Xasp, Yasp);                  { back to original aspect }
  602.   WaitToGo;
  603. end; { AspectRatioPlay }
  604.  
  605. procedure TextPlay;
  606. { Demonstrate text justifications and text sizing }
  607. var
  608.   Size : word;
  609.   W, H, X, Y : word;
  610.   ViewInfo : ViewPortType;
  611. begin
  612.   MainWindow('SetTextJustify / SetUserCharSize demo');
  613.   GetViewSettings(ViewInfo);
  614.   with ViewInfo do
  615.   begin
  616.     SetTextStyle(TriplexFont, VertDir, 4);
  617.     Y := (y2-y1) - 2;
  618.     SetTextJustify(CenterText, BottomText);
  619.     OutTextXY(2*TextWidth('M'), Y, 'Vertical');
  620.     SetTextStyle(TriplexFont, HorizDir, 4);
  621.     SetTextJustify(LeftText, TopText);
  622.     OutTextXY(2*TextWidth('M'), 2, 'Horizontal');
  623.     SetTextJustify(CenterText, CenterText);
  624.     X := (x2-x1) div 2;
  625.     Y := TextHeight('H');
  626.     for Size := 1 to 4 do
  627.     begin
  628.       SetTextStyle(TriplexFont, HorizDir, Size);
  629.       H := TextHeight('M');
  630.       W := TextWidth('M');
  631.       Inc(Y, H);
  632.       OutTextXY(X, Y, 'Size '+Int2Str(Size));
  633.     end;
  634.     Inc(Y, H div 2);
  635.     SetTextJustify(CenterText, TopText);
  636.     SetUserCharSize(5, 6, 3, 2);
  637.     SetTextStyle(TriplexFont, HorizDir, UserCharSize);
  638.     OutTextXY((x2-x1) div 2, Y, 'User defined size!');
  639.   end;
  640.   WaitToGo;
  641. end; { TextPlay }
  642.  
  643. procedure TextDump;
  644. { Dump the complete character sets to the screen }
  645. const
  646.   CGASizes  : array[0..10] of word = (1, 3, 7, 3, 3, 3, 3, 3, 3, 1, 1);
  647.   NormSizes : array[0..10] of word = (1, 4, 7, 4, 4, 4, 4, 4, 4, 2, 2);
  648. var
  649.   Font : word;
  650.   ViewInfo : ViewPortType;
  651.   Ch : char;
  652. begin
  653.   for Font := 0 to 10 do
  654.   begin
  655.     MainWindow(Fonts[Font]+' character set');
  656.     GetViewSettings(ViewInfo);
  657.     with ViewInfo do
  658.     begin
  659.       SetTextJustify(LeftText, TopText);
  660.       MoveTo(2, 3);
  661.       if Font = DefaultFont then
  662.         begin
  663.           SetTextStyle(Font, HorizDir, 1);
  664.           Ch := #0;
  665.           repeat
  666.             OutText(Ch);
  667.             if (GetX + TextWidth('M')) > (x2-x1) then
  668.               MoveTo(2, GetY + TextHeight('M')+3);
  669.             Ch := Succ(Ch);
  670.           until (Ch >= #255);
  671.         end
  672.       else
  673.         begin
  674.           if MaxY < 200 then
  675.             SetTextStyle(Font, HorizDir, CGASizes[Font])
  676.           else
  677.             SetTextStyle(Font, HorizDir, NormSizes[Font]);
  678.           Ch := '!';
  679.           repeat
  680.             OutText(Ch);
  681.             if (GetX + TextWidth('M')) > (x2-x1) then
  682.               MoveTo(2, GetY + TextHeight('M')+3);
  683.             Ch := Succ(Ch);
  684.           until (Ch >= #255);
  685.         end;
  686.     end; { with }
  687.     WaitToGo;
  688.   end; { for loop }
  689. end; { TextDump }
  690.  
  691. procedure LineToPlay;
  692. { Demonstrate MoveTo and LineTo commands }
  693. const
  694.   MaxPoints = 15;
  695. var
  696.   Points     : array[0..MaxPoints] of PointType;
  697.   ViewInfo   : ViewPortType;
  698.   I, J       : integer;
  699.   CenterX    : integer;   { The center point of the circle }
  700.   CenterY    : integer;
  701.   Radius     : word;
  702.   StepAngle  : word;
  703.   Xasp, Yasp : word;
  704.   Radians    : real;
  705.  
  706. function AdjAsp(Value : integer) : integer;
  707. { Adjust a value for the aspect ratio of the device }
  708. begin
  709.   AdjAsp := (LongInt(Value) * Xasp) div Yasp;
  710. end; { AdjAsp }
  711.  
  712. begin
  713.   MainWindow('MoveTo, LineTo demonstration');
  714.   GetAspectRatio(Xasp, Yasp);
  715.   GetViewSettings(ViewInfo);
  716.   with ViewInfo do
  717.   begin
  718.     CenterX := (x2-x1) div 2;
  719.     CenterY := (y2-y1) div 2;
  720.     Radius := CenterY;
  721.     while (CenterY+AdjAsp(Radius)) < (y2-y1)-20 do
  722.       Inc(Radius);
  723.   end;
  724.   StepAngle := 360 div MaxPoints;
  725.   for I := 0 to MaxPoints - 1 do
  726.   begin
  727.     Radians := (StepAngle * I) * Pi / 180;
  728.     Points[I].X := CenterX + round(Cos(Radians) * Radius);
  729.     Points[I].Y := CenterY - AdjAsp(round(Sin(Radians) * Radius));
  730.   end;
  731.   Circle(CenterX, CenterY, Radius);
  732.   for I := 0 to MaxPoints - 1 do
  733.   begin
  734.     for J := I to MaxPoints - 1 do
  735.     begin
  736.       MoveTo(Points[I].X, Points[I].Y);
  737.       LineTo(Points[J].X, Points[J].Y);
  738.     end;
  739.   end;
  740.   WaitToGo;
  741. end; { LineToPlay }
  742.  
  743. procedure LineRelPlay;
  744. { Demonstrate MoveRel and LineRel commands }
  745. const
  746.   MaxPoints = 12;
  747. var
  748.   Poly     : array[1..MaxPoints] of PointType; { Stores a polygon for filling }
  749.   CurrPort : ViewPortType;
  750.  
  751. procedure DrawTesseract;
  752. { Draw a Tesseract on the screen with relative move and
  753.   line drawing commands, also create a polygon for filling }
  754. const
  755.   CheckerBoard : FillPatternType = (0, $10, $28, $44, $28, $10, 0, 0);
  756. var
  757.   X, Y, W, H   : integer;
  758.  
  759. begin
  760.   GetViewSettings(CurrPort);
  761.   with CurrPort do
  762.   begin
  763.     W := (x2-x1) div 9;
  764.     H := (y2-y1) div 8;
  765.     X := ((x2-x1) div 2) - round(2.5 * W);
  766.     Y := ((y2-y1) div 2) - (3 * H);
  767.  
  768.     { Border around viewport is outer part of polygon }
  769.     Poly[1].X := 0;     Poly[1].Y := 0;
  770.     Poly[2].X := x2-x1; Poly[2].Y := 0;
  771.     Poly[3].X := x2-x1; Poly[3].Y := y2-y1;
  772.     Poly[4].X := 0;     Poly[4].Y := y2-y1;
  773.     Poly[5].X := 0;     Poly[5].Y := 0;
  774.     MoveTo(X, Y);
  775.  
  776.     { Grab the whole in the polygon as we draw }
  777.     MoveRel(0, H);      Poly[6].X := GetX;  Poly[6].Y := GetY;
  778.     MoveRel(W, -H);     Poly[7].X := GetX;  Poly[7].Y := GetY;
  779.     MoveRel(4*W, 0);    Poly[8].X := GetX;  Poly[8].Y := GetY;
  780.     MoveRel(0, 5*H);    Poly[9].X := GetX;  Poly[9].Y := GetY;
  781.     MoveRel(-W, H);     Poly[10].X := GetX; Poly[10].Y := GetY;
  782.     MoveRel(-4*W, 0);   Poly[11].X := GetX; Poly[11].Y := GetY;
  783.     MoveRel(0, -5*H);   Poly[12].X := GetX; Poly[12].Y := GetY;
  784.  
  785.     { Fill the polygon with a user defined fill pattern }
  786.     SetFillPattern(CheckerBoard, MaxColor);
  787.     FillPoly(12, Poly);
  788.  
  789.     MoveRel(W, -H);
  790.     LineRel(0, 5*H);   LineRel(2*W, 0);    LineRel(0, -3*H);
  791.     LineRel(W, -H);    LineRel(0, 5*H);    MoveRel(0, -5*H);
  792.     LineRel(-2*W, 0);  LineRel(0, 3*H);    LineRel(-W, H);
  793.     MoveRel(W, -H);    LineRel(W, 0);      MoveRel(0, -2*H);
  794.     LineRel(-W, 0);
  795.  
  796.     { Flood fill the center }
  797.     FloodFill((x2-x1) div 2, (y2-y1) div 2, MaxColor);
  798.   end;
  799. end; { DrawTesseract }
  800.  
  801. begin
  802.   MainWindow('LineRel / MoveRel demonstration');
  803.   GetViewSettings(CurrPort);
  804.   with CurrPort do
  805.     { Move the viewport out 1 pixel from each end }
  806.     SetViewPort(x1-1, y1-1, x2+1, y2+1, ClipOn);
  807.   DrawTesseract;
  808.   WaitToGo;
  809. end; { LineRelPlay }
  810.  
  811. procedure PiePlay;
  812. { Demonstrate  PieSlice and GetAspectRatio commands }
  813. var
  814.   ViewInfo   : ViewPortType;
  815.   CenterX    : integer;
  816.   CenterY    : integer;
  817.   Radius     : word;
  818.   Xasp, Yasp : word;
  819.   X, Y       : integer;
  820.  
  821. function AdjAsp(Value : integer) : integer;
  822. { Adjust a value for the aspect ratio of the device }
  823. begin
  824.   AdjAsp := (LongInt(Value) * Xasp) div Yasp;
  825. end; { AdjAsp }
  826.  
  827. procedure GetTextCoords(AngleInDegrees, Radius : word; var X, Y : integer);
  828. { Get the coordinates of text for pie slice labels }
  829. var
  830.   Radians : real;
  831. begin
  832.   Radians := AngleInDegrees * Pi / 180;
  833.   X := round(Cos(Radians) * Radius);
  834.   Y := round(Sin(Radians) * Radius);
  835. end; { GetTextCoords }
  836.  
  837. begin
  838.   MainWindow('PieSlice / GetAspectRatio demonstration');
  839.   GetAspectRatio(Xasp, Yasp);
  840.   GetViewSettings(ViewInfo);
  841.   with ViewInfo do
  842.   begin
  843.     CenterX := (x2-x1) div 2;
  844.     CenterY := ((y2-y1) div 2) + 20;
  845.     Radius := (y2-y1) div 3;
  846.     while AdjAsp(Radius) < round((y2-y1) / 3.6) do
  847.       Inc(Radius);
  848.   end;
  849.   SetTextStyle(TriplexFont, HorizDir, 4);
  850.   SetTextJustify(CenterText, TopText);
  851.   OutTextXY(CenterX, 0, 'This is a pie chart!');
  852.  
  853.   SetTextStyle(TriplexFont, HorizDir, 3);
  854.  
  855.   SetFillStyle(SolidFill, RandColor);
  856.   PieSlice(CenterX+10, CenterY-AdjAsp(10), 0, 90, Radius);
  857.   GetTextCoords(45, Radius, X, Y);
  858.   SetTextJustify(LeftText, BottomText);
  859.   OutTextXY(CenterX+10+X+TextWidth('H'), CenterY-AdjAsp(10+Y), '25 %');
  860.  
  861.   SetFillStyle(HatchFill, RandColor);
  862.   PieSlice(CenterX, CenterY, 225, 360, Radius);
  863.   GetTextCoords(293, Radius, X, Y);
  864.   SetTextJustify(LeftText, TopText);
  865.   OutTextXY(CenterX+X+TextWidth('H'), CenterY-AdjAsp(Y), '37.5 %');
  866.  
  867.   SetFillStyle(InterleaveFill, RandColor);
  868.   PieSlice(CenterX-10, CenterY, 135, 225, Radius);
  869.   GetTextCoords(180, Radius, X, Y);
  870.   SetTextJustify(RightText, CenterText);
  871.   OutTextXY(CenterX-10+X-TextWidth('H'), CenterY-AdjAsp(Y), '25 %');
  872.  
  873.   SetFillStyle(WideDotFill, RandColor);
  874.   PieSlice(CenterX, CenterY, 90, 135, Radius);
  875.   GetTextCoords(112, Radius, X, Y);
  876.   SetTextJustify(RightText, BottomText);
  877.   OutTextXY(CenterX+X-TextWidth('H'), CenterY-AdjAsp(Y), '12.5 %');
  878.  
  879.   WaitToGo;
  880. end; { PiePlay }
  881.  
  882. procedure Bar3DPlay;
  883. { Demonstrate Bar3D command }
  884. const
  885.   NumBars   = 7;  { The number of bars drawn }
  886.   BarHeight : array[1..NumBars] of byte = (1, 3, 2, 5, 4, 2, 1);
  887.   YTicks    = 5;  { The number of tick marks on the Y axis }
  888. var
  889.   ViewInfo : ViewPortType;
  890.   H        : word;
  891.   XStep    : real;
  892.   YStep    : real;
  893.   I, J     : integer;
  894.   Depth    : word;
  895.   Color    : word;
  896. begin
  897.   MainWindow('Bar3D / Rectangle demonstration');
  898.   H := 3*TextHeight('M');
  899.   GetViewSettings(ViewInfo);
  900.   SetTextJustify(CenterText, TopText);
  901.   SetTextStyle(TriplexFont, HorizDir, 4);
  902.   OutTextXY(MaxX div 2, 6, 'These are 3D bars !');
  903.   SetTextStyle(DefaultFont, HorizDir, 1);
  904.   with ViewInfo do
  905.     SetViewPort(x1+50, y1+40, x2-50, y2-10, ClipOn);
  906.   GetViewSettings(ViewInfo);
  907.   with ViewInfo do
  908.   begin
  909.     Line(H, H, H, (y2-y1)-H);
  910.     Line(H, (y2-y1)-H, (x2-x1)-H, (y2-y1)-H);
  911.     YStep := ((y2-y1)-(2*H)) / YTicks;
  912.     XStep := ((x2-x1)-(2*H)) / NumBars;
  913.     J := (y2-y1)-H;
  914.     SetTextJustify(CenterText, CenterText);
  915.  
  916.     { Draw the Y axis and ticks marks }
  917.     for I := 0 to Yticks do
  918.     begin
  919.       Line(H div 2, J, H, J);
  920.       OutTextXY(0, J, Int2Str(I));
  921.       J := Round(J-Ystep);
  922.     end;
  923.  
  924.  
  925.     Depth := trunc(0.25 * XStep);    { Calculate depth of bar }
  926.  
  927.     { Draw X axis, bars, and tick marks }
  928.     SetTextJustify(CenterText, TopText);
  929.     J := H;
  930.     for I := 1 to Succ(NumBars) do
  931.     begin
  932.       SetColor(MaxColor);
  933.       Line(J, (y2-y1)-H, J, (y2-y1-3)-(H div 2));
  934.       OutTextXY(J, (y2-y1)-(H div 2), Int2Str(I-1));
  935.       if I <> Succ(NumBars) then
  936.       begin
  937.         Color := RandColor;
  938.         SetFillStyle(I, Color);
  939.         SetColor(Color);
  940.         Bar3D(J, round((y2-y1-H)-(BarHeight[I] * Ystep)),
  941.                  round(J+Xstep-Depth), round((y2-y1)-H-1), Depth, TopOn);
  942.         J := Round(J+Xstep);
  943.       end;
  944.     end;
  945.  
  946.   end;
  947.   WaitToGo;
  948. end; { Bar3DPlay }
  949.  
  950. procedure BarPlay;
  951. { Demonstrate Bar command }
  952. const
  953.   NumBars   = 5;
  954.   BarHeight : array[1..NumBars] of byte = (1, 3, 5, 2, 4);
  955.   Styles    : array[1..NumBars] of byte = (1, 3, 10, 5, 9);
  956. var
  957.   ViewInfo  : ViewPortType;
  958.   BarNum    : word;
  959.   H         : word;
  960.   XStep     : real;
  961.   YStep     : real;
  962.   I, J      : integer;
  963.   Color     : word;
  964. begin
  965.   MainWindow('Bar / Rectangle demonstration');
  966.   H := 3*TextHeight('M');
  967.   GetViewSettings(ViewInfo);
  968.   SetTextJustify(CenterText, TopText);
  969.   SetTextStyle(TriplexFont, HorizDir, 4);
  970.   OutTextXY(MaxX div 2, 6, 'These are 2D bars !');
  971.   SetTextStyle(DefaultFont, HorizDir, 1);
  972.   with ViewInfo do
  973.     SetViewPort(x1+50, y1+30, x2-50, y2-10, ClipOn);
  974.   GetViewSettings(ViewInfo);
  975.   with ViewInfo do
  976.   begin
  977.     Line(H, H, H, (y2-y1)-H);
  978.     Line(H, (y2-y1)-H, (x2-x1)-H, (y2-y1)-H);
  979.     YStep := ((y2-y1)-(2*H)) / NumBars;
  980.     XStep := ((x2-x1)-(2*H)) / NumBars;
  981.     J := (y2-y1)-H;
  982.     SetTextJustify(CenterText, CenterText);
  983.  
  984.     { Draw Y axis with tick marks }
  985.     for I := 0 to NumBars do
  986.     begin
  987.       Line(H div 2, J, H, J);
  988.       OutTextXY(0, J, Int2Str(i));
  989.       J := Round(J-Ystep);
  990.     end;
  991.  
  992.     { Draw X axis, bars, and tick marks }
  993.     J := H;
  994.     SetTextJustify(CenterText, TopText);
  995.     for I := 1 to Succ(NumBars) do
  996.     begin
  997.       SetColor(MaxColor);
  998.       Line(J, (y2-y1)-H, J, (y2-y1-3)-(H div 2));
  999.       OutTextXY(J, (y2-y1)-(H div 2), Int2Str(I));
  1000.       if I <> Succ(NumBars) then
  1001.       begin
  1002.         Color := RandColor;
  1003.         SetFillStyle(Styles[I], Color);
  1004.         SetColor(Color);
  1005.         Bar(J, round((y2-y1-H)-(BarHeight[I] * Ystep)), round(J+Xstep), (y2-y1)-H-1);
  1006.         Rectangle(J, round((y2-y1-H)-(BarHeight[I] * Ystep)), round(J+Xstep), (y2-y1)-H-1);
  1007.       end;
  1008.       J := Round(J+Xstep);
  1009.     end;
  1010.  
  1011.   end;
  1012.   WaitToGo;
  1013. end; { BarPlay }
  1014.  
  1015. procedure CirclePlay;
  1016. { Draw random circles on the screen }
  1017. var
  1018.   MaxRadius : word;
  1019. begin
  1020.   MainWindow('Circle demonstration');
  1021.   StatusLine('Esc aborts or press a key');
  1022.   MaxRadius := MaxY div 10;
  1023.   SetLineStyle(SolidLn, 0, NormWidth);
  1024.   repeat
  1025.     SetColor(RandColor);
  1026.     Circle(Random(MaxX), Random(MaxY), Random(MaxRadius));
  1027.   until KeyPressed;
  1028.   WaitToGo;
  1029. end; { CirclePlay }
  1030.  
  1031.  
  1032. procedure RandBarPlay;
  1033. { Draw random bars on the screen }
  1034. var
  1035.   MaxWidth  : integer;
  1036.   MaxHeight : integer;
  1037.   ViewInfo  : ViewPortType;
  1038.   Color     : word;
  1039. begin
  1040.   MainWindow('Random Bars');
  1041.   StatusLine('Esc aborts or press a key');
  1042.   GetViewSettings(ViewInfo);
  1043.   with ViewInfo do
  1044.   begin
  1045.     MaxWidth := x2-x1;
  1046.     MaxHeight := y2-y1;
  1047.   end;
  1048.   repeat
  1049.     Color := RandColor;
  1050.     SetColor(Color);
  1051.     SetFillStyle(Random(CloseDotFill)+1, Color);
  1052.     Bar3D(Random(MaxWidth), Random(MaxHeight),
  1053.           Random(MaxWidth), Random(MaxHeight), 0, TopOff);
  1054.   until KeyPressed;
  1055.   WaitToGo;
  1056. end; { RandBarPlay }
  1057.  
  1058. procedure ArcPlay;
  1059. { Draw random arcs on the screen }
  1060. var
  1061.   MaxRadius : word;
  1062.   EndAngle : word;
  1063.   ArcInfo : ArcCoordsType;
  1064. begin
  1065.   MainWindow('Arc / GetArcCoords demonstration');
  1066.   StatusLine('Esc aborts or press a key');
  1067.   MaxRadius := MaxY div 10;
  1068.   repeat
  1069.     SetColor(RandColor);
  1070.     EndAngle := Random(360);
  1071.     SetLineStyle(SolidLn, 0, NormWidth);
  1072.     Arc(Random(MaxX), Random(MaxY), Random(EndAngle), EndAngle, Random(MaxRadius));
  1073.     GetArcCoords(ArcInfo);
  1074.     with ArcInfo do
  1075.     begin
  1076.       Line(X, Y, XStart, YStart);
  1077.       Line(X, Y, Xend, Yend);
  1078.     end;
  1079.   until KeyPressed;
  1080.   WaitToGo;
  1081. end; { ArcPlay }
  1082.  
  1083. procedure PutPixelPlay;
  1084. { Demonstrate the PutPixel and GetPixel commands }
  1085. const
  1086.   Seed   = 1962; { A seed for the random number generator }
  1087.   NumPts = 2000; { The number of pixels plotted }
  1088.   Esc    = #27;
  1089. var
  1090.   I : word;
  1091.   X, Y, Color : word;
  1092.   XMax, YMax  : integer;
  1093.   ViewInfo    : ViewPortType;
  1094. begin
  1095.   MainWindow('PutPixel / GetPixel demonstration');
  1096.   StatusLine('Esc aborts or press a key...');
  1097.  
  1098.   GetViewSettings(ViewInfo);
  1099.   with ViewInfo do
  1100.   begin
  1101.     XMax := (x2-x1-1);
  1102.     YMax := (y2-y1-1);
  1103.   end;
  1104.  
  1105.   while not KeyPressed do
  1106.   begin
  1107.     { Plot random pixels }
  1108.     RandSeed := Seed;
  1109.     I := 0;
  1110.     while (not KeyPressed) and (I < NumPts) do
  1111.     begin
  1112.       Inc(I);
  1113.       PutPixel(Random(XMax)+1, Random(YMax)+1, RandColor);
  1114.     end;
  1115.  
  1116.     { Erase pixels }
  1117.     RandSeed := Seed;
  1118.     I := 0;
  1119.     while (not KeyPressed) and (I < NumPts) do
  1120.     begin
  1121.       Inc(I);
  1122.       X := Random(XMax)+1;
  1123.       Y := Random(YMax)+1;
  1124.       Color := GetPixel(X, Y);
  1125.       if Color = RandColor then
  1126.         PutPixel(X, Y, 0);
  1127.     end;
  1128.   end;
  1129.   WaitToGo;
  1130. end; { PutPixelPlay }
  1131.  
  1132. procedure PutImagePlay;
  1133. { Demonstrate the GetImage and PutImage commands }
  1134.  
  1135. const
  1136.   r  = 20;
  1137.   StartX = 100;
  1138.   StartY = 50;
  1139.  
  1140. var
  1141.   CurPort : ViewPortType;
  1142.  
  1143. procedure MoveSaucer(var X, Y : integer; Width, Height : integer);
  1144. var
  1145.   Step : integer;
  1146. begin
  1147.   Step := Random(2*r);
  1148.   if Odd(Step) then
  1149.     Step := -Step;
  1150.   X := X + Step;
  1151.   Step := Random(r);
  1152.   if Odd(Step) then
  1153.     Step := -Step;
  1154.   Y := Y + Step;
  1155.  
  1156.   { Make saucer bounce off viewport walls }
  1157.   with CurPort do
  1158.   begin
  1159.     if (x1 + X + Width - 1 > x2) then
  1160.       X := x2-x1 - Width + 1
  1161.     else
  1162.       if (X < 0) then
  1163.         X := 0;
  1164.     if (y1 + Y + Height - 1 > y2) then
  1165.       Y := y2-y1 - Height + 1
  1166.     else
  1167.       if (Y < 0) then
  1168.         Y := 0;
  1169.   end;
  1170. end; { MoveSaucer }
  1171.  
  1172. var
  1173.   Pausetime : word;
  1174.   Saucer    : pointer;
  1175.   X, Y      : integer;
  1176.   ulx, uly  : word;
  1177.   lrx, lry  : word;
  1178.   Size      : word;
  1179.   I         : word;
  1180. begin
  1181.   ClearDevice;
  1182.   FullPort;
  1183.  
  1184.   { PaintScreen }
  1185.   ClearDevice;
  1186.   MainWindow('GetImage / PutImage Demonstration');
  1187.   StatusLine('Esc aborts or press a key...');
  1188.   GetViewSettings(CurPort);
  1189.  
  1190.   { DrawSaucer }
  1191.   Ellipse(StartX, StartY, 0, 360, r, (r div 3)+2);
  1192.   Ellipse(StartX, StartY-4, 190, 357, r, r div 3);
  1193.   Line(StartX+7, StartY-6, StartX+10, StartY-12);
  1194.   Circle(StartX+10, StartY-12, 2);
  1195.   Line(StartX-7, StartY-6, StartX-10, StartY-12);
  1196.   Circle(StartX-10, StartY-12, 2);
  1197.   SetFillStyle(SolidFill, MaxColor);
  1198.   FloodFill(StartX+1, StartY+4, GetColor);
  1199.  
  1200.   { ReadSaucerImage }
  1201.   ulx := StartX-(r+1);
  1202.   uly := StartY-14;
  1203.   lrx := StartX+(r+1);
  1204.   lry := StartY+(r div 3)+3;
  1205.  
  1206.   Size := ImageSize(ulx, uly, lrx, lry);
  1207.   GetMem(Saucer, Size);
  1208.   GetImage(ulx, uly, lrx, lry, Saucer^);
  1209.   PutImage(ulx, uly, Saucer^, XORput);               { erase image }
  1210.  
  1211.   { Plot some "stars" }
  1212.   for I := 1 to 1000 do
  1213.     PutPixel(Random(MaxX), Random(MaxY), RandColor);
  1214.   X := MaxX div 2;
  1215.   Y := MaxY div 2;
  1216.   PauseTime := 70;
  1217.  
  1218.   { Move the saucer around }
  1219.   repeat
  1220.     PutImage(X, Y, Saucer^, XORput);                 { draw image }
  1221.     Delay(PauseTime);
  1222.     PutImage(X, Y, Saucer^, XORput);                 { erase image }
  1223.     MoveSaucer(X, Y, lrx - ulx + 1, lry - uly + 1);  { width/height }
  1224.   until KeyPressed;
  1225.   FreeMem(Saucer, size);
  1226.   WaitToGo;
  1227. end; { PutImagePlay }
  1228.  
  1229. procedure PolyPlay;
  1230. { Draw random polygons with random fill styles on the screen }
  1231. const
  1232.   MaxPts = 5;
  1233. type
  1234.   PolygonType = array[1..MaxPts] of PointType;
  1235. var
  1236.   Poly : PolygonType;
  1237.   I, Color : word;
  1238. begin
  1239.   MainWindow('FillPoly demonstration');
  1240.   StatusLine('Esc aborts or press a key...');
  1241.   repeat
  1242.     Color := RandColor;
  1243.     SetFillStyle(Random(11)+1, Color);
  1244.     SetColor(Color);
  1245.     for I := 1 to MaxPts do
  1246.       with Poly[I] do
  1247.       begin
  1248.         X := Random(MaxX);
  1249.         Y := Random(MaxY);
  1250.       end;
  1251.     FillPoly(MaxPts, Poly);
  1252.   until KeyPressed;
  1253.   WaitToGo;
  1254. end; { PolyPlay }
  1255.  
  1256. procedure FillStylePlay;
  1257. { Display all of the predefined fill styles available }
  1258. var
  1259.   Style    : word;
  1260.   Width    : word;
  1261.   Height   : word;
  1262.   X, Y     : word;
  1263.   I, J     : word;
  1264.   ViewInfo : ViewPortType;
  1265.  
  1266. procedure DrawBox(X, Y : word);
  1267. begin
  1268.   SetFillStyle(Style, MaxColor);
  1269.   with ViewInfo do
  1270.     Bar(X, Y, X+Width, Y+Height);
  1271.   Rectangle(X, Y, X+Width, Y+Height);
  1272.   OutTextXY(X+(Width div 2), Y+Height+4, Int2Str(Style));
  1273.   Inc(Style);
  1274. end; { DrawBox }
  1275.  
  1276. begin
  1277.   MainWindow('Pre-defined fill styles');
  1278.   GetViewSettings(ViewInfo);
  1279.   with ViewInfo do
  1280.   begin
  1281.     Width := 2 * ((x2+1) div 13);
  1282.     Height := 2 * ((y2-10) div 10);
  1283.   end;
  1284.   X := Width div 2;
  1285.   Y := Height div 2;
  1286.   Style := 0;
  1287.   for J := 1 to 3 do
  1288.   begin
  1289.     for I := 1 to 4 do
  1290.     begin
  1291.       DrawBox(X, Y);
  1292.       Inc(X, (Width div 2) * 3);
  1293.     end;
  1294.     X := Width div 2;
  1295.     Inc(Y, (Height div 2) * 3);
  1296.   end;
  1297.   SetTextJustify(LeftText, TopText);
  1298.   WaitToGo;
  1299. end; { FillStylePlay }
  1300.  
  1301. procedure FillPatternPlay;
  1302. { Display some user defined fill patterns }
  1303. const
  1304.   Patterns : array[0..11] of FillPatternType = (
  1305.   ($AA, $55, $AA, $55, $AA, $55, $AA, $55),
  1306.   ($33, $33, $CC, $CC, $33, $33, $CC, $CC),
  1307.   ($F0, $F0, $F0, $F0, $F, $F, $F, $F),
  1308.   (0, $10, $28, $44, $28, $10, 0, 0),
  1309.   (0, $70, $20, $27, $25, $27, $4, $4),
  1310.   (0, 0, 0, $18, $18, 0, 0, 0),
  1311.   (0, 0, $3C, $3C, $3C, $3C, 0, 0),
  1312.   (0, $7E, $7E, $7E, $7E, $7E, $7E, 0),
  1313.   (0, 0, $22, $8, 0, $22, $1C, 0),
  1314.   ($FF, $7E, $3C, $18, $18, $3C, $7E, $FF),
  1315.   (0, $10, $10, $7C, $10, $10, 0, 0),
  1316.   (0, $42, $24, $18, $18, $24, $42, 0));
  1317. var
  1318.   Style    : word;
  1319.   Width    : word;
  1320.   Height   : word;
  1321.   X, Y     : word;
  1322.   I, J     : word;
  1323.   ViewInfo : ViewPortType;
  1324.  
  1325. procedure DrawBox(X, Y : word);
  1326. begin
  1327.   SetFillPattern(Patterns[Style], MaxColor);
  1328.   with ViewInfo do
  1329.     Bar(X, Y, X+Width, Y+Height);
  1330.   Rectangle(X, Y, X+Width, Y+Height);
  1331.   Inc(Style);
  1332. end; { DrawBox }
  1333.  
  1334. begin
  1335.   MainWindow('User defined fill styles');
  1336.   GetViewSettings(ViewInfo);
  1337.   with ViewInfo do
  1338.   begin
  1339.     Width := 2 * ((x2+1) div 13);
  1340.     Height := 2 * ((y2-10) div 10);
  1341.   end;
  1342.   X := Width div 2;
  1343.   Y := Height div 2;
  1344.   Style := 0;
  1345.   for J := 1 to 3 do
  1346.   begin
  1347.     for I := 1 to 4 do
  1348.     begin
  1349.       DrawBox(X, Y);
  1350.       Inc(X, (Width div 2) * 3);
  1351.     end;
  1352.     X := Width div 2;
  1353.     Inc(Y, (Height div 2) * 3);
  1354.   end;
  1355.   SetTextJustify(LeftText, TopText);
  1356.   WaitToGo;
  1357. end; { FillPatternPlay }
  1358.  
  1359. procedure ColorPlay;
  1360. { Display all of the colors available for the current driver and mode }
  1361. var
  1362.   Color    : word;
  1363.   Width    : word;
  1364.   Height   : word;
  1365.   X, Y     : word;
  1366.   I, J     : word;
  1367.   ViewInfo : ViewPortType;
  1368.  
  1369. procedure DrawBox(X, Y : word);
  1370. begin
  1371.   SetFillStyle(SolidFill, Color);
  1372.   SetColor(Color);
  1373.   with ViewInfo do
  1374.     Bar(X, Y, X+Width, Y+Height);
  1375.   Rectangle(X, Y, X+Width, Y+Height);
  1376.   Color := GetColor;
  1377.   if Color = 0 then
  1378.   begin
  1379.     SetColor(MaxColor);
  1380.     Rectangle(X, Y, X+Width, Y+Height);
  1381.   end;
  1382.   OutTextXY(X+(Width div 2), Y+Height+4, Int2Str(Color));
  1383.   Color := Succ(Color) mod (MaxColor + 1);
  1384. end; { DrawBox }
  1385.  
  1386. begin
  1387.   MainWindow('Color demonstration');
  1388.   Color := 1;
  1389.   GetViewSettings(ViewInfo);
  1390.   with ViewInfo do
  1391.   begin
  1392.     Width := 2 * ((x2+1) div 16);
  1393.     Height := 2 * ((y2-10) div 10);
  1394.   end;
  1395.   X := Width div 2;
  1396.   Y := Height div 2;
  1397.   for J := 1 to 3 do
  1398.   begin
  1399.     for I := 1 to 5 do
  1400.     begin
  1401.       DrawBox(X, Y);
  1402.       Inc(X, (Width div 2) * 3);
  1403.     end;
  1404.     X := Width div 2;
  1405.     Inc(Y, (Height div 2) * 3);
  1406.   end;
  1407.   WaitToGo;
  1408. end; { ColorPlay }
  1409.  
  1410. procedure PalettePlay;
  1411. { Demonstrate the use of the SetPalette command }
  1412. const
  1413.   XBars = 15;
  1414.   YBars = 10;
  1415. var
  1416.   I, J     : word;
  1417.   X, Y     : word;
  1418.   Color    : word;
  1419.   ViewInfo : ViewPortType;
  1420.   Width    : word;
  1421.   Height   : word;
  1422.   OldPal   : PaletteType;
  1423. begin
  1424.   GetPalette(OldPal);
  1425.   MainWindow('Palette demonstration');
  1426.   StatusLine('Press any key...');
  1427.   GetViewSettings(ViewInfo);
  1428.   with ViewInfo do
  1429.   begin
  1430.     Width := (x2-x1) div XBars;
  1431.     Height := (y2-y1) div YBars;
  1432.   end;
  1433.   X := 0; Y := 0;
  1434.   Color := 0;
  1435.   for J := 1 to YBars do
  1436.   begin
  1437.     for I := 1 to XBars do
  1438.     begin
  1439.       SetFillStyle(SolidFill, Color);
  1440.       Bar(X, Y, X+Width, Y+Height);
  1441.       Inc(X, Width+1);
  1442.       Inc(Color);
  1443.       Color := Color mod (MaxColor+1);
  1444.     end;
  1445.     X := 0;
  1446.     Inc(Y, Height+1);
  1447.   end;
  1448.   repeat
  1449.     SetPalette(Random(GetMaxColor + 1), Random(65));
  1450.   until KeyPressed;
  1451.   SetAllPalette(OldPal);
  1452.   WaitToGo;
  1453. end; { PalettePlay }
  1454.  
  1455. procedure CrtModePlay;
  1456. { Demonstrate the use of RestoreCrtMode and SetGraphMode }
  1457. var
  1458.   ViewInfo : ViewPortType;
  1459.   Ch       : char;
  1460. begin
  1461.   MainWindow('SetGraphMode / RestoreCrtMode demo');
  1462.   GetViewSettings(ViewInfo);
  1463.   SetTextJustify(CenterText, CenterText);
  1464.   with ViewInfo do
  1465.   begin
  1466.     OutTextXY((x2-x1) div 2, (y2-y1) div 2, 'Now you are in graphics mode');
  1467.     StatusLine('Press any key for text mode...');
  1468.     repeat until KeyPressed;
  1469.     Ch := ReadKey;
  1470.     if ch = #0 then ch := readkey;    { trap function keys }
  1471.     RestoreCrtmode;
  1472.     Writeln('Now you are in text mode.');
  1473.     Write('Press any key to go back to graphics...');
  1474.     repeat until KeyPressed;
  1475.     Ch := ReadKey;
  1476.     if ch = #0 then ch := readkey;    { trap function keys }
  1477.     SetGraphMode(GetGraphMode);
  1478.     MainWindow('SetGraphMode / RestoreCrtMode demo');
  1479.     SetTextJustify(CenterText, CenterText);
  1480.     OutTextXY((x2-x1) div 2, (y2-y1) div 2, 'Back in graphics mode...');
  1481.   end;
  1482.   WaitToGo;
  1483. end; { CrtModePlay }
  1484.  
  1485. procedure LineStylePlay;
  1486. { Demonstrate the predefined line styles available }
  1487. var
  1488.   Style    : word;
  1489.   Step     : word;
  1490.   X, Y     : word;
  1491.   ViewInfo : ViewPortType;
  1492.  
  1493. begin
  1494.   ClearDevice;
  1495.   DefaultColors;
  1496.   MainWindow('Pre-defined line styles');
  1497.   GetViewSettings(ViewInfo);
  1498.   with ViewInfo do
  1499.   begin
  1500.     X := 35;
  1501.     Y := 10;
  1502.     Step := (x2-x1) div 11;
  1503.     SetTextJustify(LeftText, TopText);
  1504.     OutTextXY(X, Y, 'NormWidth');
  1505.     SetTextJustify(CenterText, TopText);
  1506.     for Style := 0 to 3 do
  1507.     begin
  1508.       SetLineStyle(Style, 0, NormWidth);
  1509.       Line(X, Y+20, X, Y2-40);
  1510.       OutTextXY(X, Y2-30, Int2Str(Style));
  1511.       Inc(X, Step);
  1512.     end;
  1513.     Inc(X, 2*Step);
  1514.     SetTextJustify(LeftText, TopText);
  1515.     OutTextXY(X, Y, 'ThickWidth');
  1516.     SetTextJustify(CenterText, TopText);
  1517.     for Style := 0 to 3 do
  1518.     begin
  1519.       SetLineStyle(Style, 0, ThickWidth);
  1520.       Line(X, Y+20, X, Y2-40);
  1521.       OutTextXY(X, Y2-30, Int2Str(Style));
  1522.       Inc(X, Step);
  1523.     end;
  1524.   end;
  1525.   SetTextJustify(LeftText, TopText);
  1526.   WaitToGo;
  1527. end; { LineStylePlay }
  1528.  
  1529. procedure UserLineStylePlay;
  1530. { Demonstrate user defined line styles }
  1531. var
  1532.   Style    : word;
  1533.   X, Y, I  : word;
  1534.   ViewInfo : ViewPortType;
  1535. begin
  1536.   MainWindow('User defined line styles');
  1537.   GetViewSettings(ViewInfo);
  1538.   with ViewInfo do
  1539.   begin
  1540.     X := 4;
  1541.     Y := 10;
  1542.     Style := 0;
  1543.     I := 0;
  1544.     while X < X2-4 do
  1545.     begin
  1546.       {$B+}
  1547.       Style := Style or (1 shl (I mod 16));
  1548.       {$B-}
  1549.       SetLineStyle(UserBitLn, Style, NormWidth);
  1550.       Line(X, Y, X, (y2-y1)-Y);
  1551.       Inc(X, 5);
  1552.       Inc(I);
  1553.       if Style = 65535 then
  1554.       begin
  1555.         I := 0;
  1556.         Style := 0;
  1557.       end;
  1558.     end;
  1559.   end;
  1560.   WaitToGo;
  1561. end; { UserLineStylePlay }
  1562.  
  1563.  
  1564. procedure SayGoodbye;
  1565. { Say goodbye and then exit the program }
  1566. var
  1567.   ViewInfo : ViewPortType;
  1568. begin
  1569.   MainWindow('');
  1570.   GetViewSettings(ViewInfo);
  1571.   SetTextStyle(TriplexFont, HorizDir, 4);
  1572.   SetTextJustify(CenterText, CenterText);
  1573.   with ViewInfo do
  1574.     OutTextXY((x2-x1) div 2, (y2-y1) div 2, 'That''s all folks!');
  1575.   StatusLine('Press any key to quit...');
  1576.   repeat until KeyPressed;
  1577. end; { SayGoodbye }
  1578.  
  1579. begin { program body }
  1580.   Initialize;
  1581.   ReportStatus;
  1582.  
  1583.   AspectRatioPlay;
  1584.   FillEllipsePlay;
  1585.   SectorPlay;
  1586.   WriteModePlay;
  1587.  
  1588.   ColorPlay;
  1589.   { PalettePlay only intended to work on these drivers: }
  1590.   if (GraphDriver = EGA) or
  1591.      (GraphDriver = EGA64) or
  1592.      (GraphDriver = VGA) or
  1593.      (GraphDriver = VESA16 - LastDriverNum) then
  1594.     PalettePlay;
  1595.   PutPixelPlay;
  1596.   PutImagePlay;
  1597.   RandBarPlay;
  1598.   BarPlay;
  1599.   Bar3DPlay;
  1600.   ArcPlay;
  1601.   CirclePlay;
  1602.   PiePlay;
  1603.   LineToPlay;
  1604.   LineRelPlay;
  1605.   LineStylePlay;
  1606.   UserLineStylePlay;
  1607.   TextDump;
  1608.   TextPlay;
  1609.   CrtModePlay;
  1610.   FillStylePlay;
  1611.   FillPatternPlay;
  1612.   PolyPlay;
  1613.   SayGoodbye;
  1614.   CloseGraph;
  1615. end.
  1616.